// nodeMCU Amica V2 Module mit ESP8266 12E - WiFiWebClient+DHT22+LDR
// Board: NodeMCU 1.0 (ESP12E Module) - 2019-12-13 22:43
 
#include <ESP8266WiFi.h> 
#include "DHT.h"
#define ssid      "mrge-ap-bu46"
#define password  ""
#define host      "10.50.20.xx"
#define httpPort  80
 
#define DHTPIN D5 
#define DHTTYPE DHT22
DHT dht(DHTPIN, DHTTYPE);
 
void setup() {
  Serial.begin(115200); Serial.println("\nWiFiWebClient-1+DHT22+LDR");
  WiFi.mode(WIFI_STA); pinMode(D0,OUTPUT); digitalWrite(D0,LOW);
  WiFi.begin(ssid, password);
  Serial.println("Verbinde mit " + String(ssid));
  while (WiFi.status() != WL_CONNECTED) {
    Serial.print("."); delay(500);
  }
  Serial.println("\nWiFi verbunden mit " + String(ssid));
  Serial.println("IP address: " + WiFi.localIP().toString());
  dht.begin();
}
 
void loop() {
  digitalWrite(D0,HIGH);
  delay(5000); 
  digitalWrite(D0,LOW);
  int ldr = analogRead(A0);
  float h = dht.readHumidity();
  float t = dht.readTemperature();
  if (isnan(h) || isnan(t)) {   // falls ein Messwert nicht ...
    Serial.println("Problem beim Lesen eines der Messwerte");
    return;
  }
 
  Serial.println("\nVerbinde mit " + String(host));
  WiFiClient client;                    // Verbindung zum Webserver
  if (!client.connect(host, httpPort)) {
    Serial.println("connection failed");
    return;
  }
  Serial.println("WiFi verbunden per " + String(ssid) +
                 " mit " + String(host));
  String pfad = "/test.php";
 
  String mw1 = String(h);
  String mw2 = String(t);
  String mw3 = String(ldr);
  String query = "?mw1=" + mw1;
         query+= "&mw2=" + mw2;
         query+= "&mw3=" + mw3;
 
  Serial.println("http://" + String(host) + pfad + query);
 
  // Anfrage an Webserver
  client.print(String("GET ") + pfad + query + " HTTP/1.1\r\n" +
               "Host: " + host + "\r\n" +
               "Connection: close\r\n\r\n");
 
  while (client.available() == 0) {} // Warte auf Anwort des Webservers
 
  while (client.available()) {       // Lies die Anwort des Webservers                
    Serial.println(client.readStringUntil('\n'));
  }
  client.stop();
  Serial.println("\nClosing connection");
}